!set n=$teller
bewerking=nivo/bewerking4.proc
somtekst$n=!record 6 of lang/remarks.$taal
nivo_title=!record 19 of lang/remarks.$taal
F=f\left(x\right)\,\,=\,\,
#functie=wisk functie
#som= latex som
#GOED= afgeleide
#goed= latex afggeleide

R=$graad
!if $graad=0
    R=$teller
!endif    
	
a=!randitem 2,3,4,5,6,7,8,9,10,-2,-3,-4,-5,-6,-7,-8,-9,-10
b=!randitem 2,3,4,5,6,7  
c=!randitem 2,3,4,5,6,7,8,9,10
d=!randitem 3,4,5,6,7,8,9,10   
e=!randitem 2,3,4,5,6 
!if $b=$d
    b=$[$b+1]
!endif
x=!randitem -5,-4,-3,-2,-1,0,1,2,3,4,5	
g=$[$d-1]

pm=!randitem +,-
mp=!randitem +,-


!if $R = 1
    functie=$a*x^$b 
    y=$[$a*($x)^$b]
    punt=($x;$y)
    opgave$n=\left\{\begin{array}{l}$F $a\cdot x^{$b} \\ \\ P $punt\end{array}
!endif
	
!if $R = 2
    functie=$a*x^$b $pm $c*x $mp $d
    y=$[$a*($x)^$b $pm $c*($x) $mp $d]
    punt=($x;$y)
    opgave$n=\left\{\begin{array}{l}$F $a\cdot x^{$b} $pm $c\cdot x $mp $d\\ \\ P $punt\end{array}
!endif
!if $R >2
    wims_texsize=+2
    x=!randitem -3,-2,-1,1,2,3
    keuze=!randitem 1,2
    !if $keuze=1
	functie=$a*x^$b $pm $c/x
	y=!exec pari $a*($x)^$b $pm $c/($x)
	punt=($x;$y)
	opgave$n=\left\{\begin{array}{l}$F $a \cdot x^{$b} $pm \frac{$c}{x} \\ \\  P $punt\end{array}
    !else
	e=!randitem 2,3
	functie=$a*x^$b $pm $c/x^$e
	y=!exec pari $a*($x)^$b $pm $c/(($x)^$e)
	punt=($x;$y)
	opgave$n=\left\{\begin{array}{l}$F $a \cdot x^{$b} $pm \frac{$c}{x^$e} \\ \\  P $punt\end{array}
    !endif   
!endif
    
sommen=!exec pari A=deriv($functie ,x)\
printtex(deriv($functie,x))\
subst(A,x,$x)
    
GOED$n=!line 3 of $sommen
afgeleide=!line 2 of $sommen
slope=!record 10 of lang/remarks.$taal
goed$n=\begin{array}{l} $(opgave$n) \rightarrow \\ \\ \left\{\begin{array}{l}f'(x) = $afgeleide\\ \\ x = $x \end{array} \rightarrow \\ \\ f'($x) = $(GOED$n) \rightarrow $slope \,=\,  $(GOED$n)

!if $plaatje=1
    x1=$[-1*(abs($x)) -2]
    x2=$[abs($x) + 2]
    y1=$[-1*(abs($y))-30] 
    y2=$[(abs($y))+30] 
    Yrange=[$y1:$y2]
    Xrange=[$x1:$x2]

    raaklijn=$(GOED$n)*x + ($y -$(GOED$n)*$x)
    linetext=!record 9 of lang/remarks.$taal
    insplot_set=size 0.6,0.6; noborder ; zeroaxis linetype 3 ; tmargin 1 ; rmargin 1 ; grid xtics ytics mxtics
    plaatje$n= $Xrange $Yrange $functie title "f(x)" ,$raaklijn  title "$linetext P($x;$y)"
!endif