!set n=$teller
!if $graad=0
    R=$teller
!else
    R=$graad
!endif        
plaatje=0
varlist=i
arglist=z
# dus z1=123i en z2=-123i als antwoord verwachten we
varcnt=1
afrondingsfactor=0
woordmax=40
somtekst$n=!record 7 of lang/remarks.$taal
bewerking=common/variable.proc

!if $R=1
    a=!randitem 1,2,3,4,5,6
    b=$[$a^2]
    opgave$n=z^{2}+$b=0
    GOED$n=$a*i,-1*$a*i
    goed$n=z^{2} = -$b \rightarrow z^{2}= $b\cdot -1 \rightarrow z=\pm \sqr{$b \cdot -1} \rightarrow z=\pm $a \cdot \sqr{-1} = $a\cdot i \vee -$a\cdot i
    !exit
!endif

!if $R=2
    a=!randitem 1,2,3,4,5,6
    b=$[$a^2]
    c=!randitem 1,2,3,4,5,6,7,8,9,-1,-2,-3,-4,-5,-6,-7,-8,-9
    opgave$n=!rawmath (z + $c)^2+$b=0
    opgave$n=!replace internal ^2 by ^{2} in $(opgave$n)
    GOED$n= $[(-1*$c)] + $a*i,$[(-1*$c)]-$a*i
    goed$n= z= $[(-1*$c)] + $a*i \vee z= $[(-1*$c)]-$a*i
    !exit
!endif

!if $R=3
    a=1
    b=!randitem 2,3,4,5,6,7,8,9
    d=$[floor(0.25*$b^2)]
    c=!randint $[$d+1],$[$d+6]	
    opgave$n=z^{2 }+ $b\cdot z + $c =0
    GOED$n=$[-0.5*$b] + i*sqrt($[$c - 0.25*$b^2 ]),$[-0.5*$b] - i*sqrt($[$c - 0.25*$b^2])
    goed$n=z= $[-0.5*$b] + i\cdot \sqrt($[$c - 0.25*$b^2 ]) \vee z= $[-0.5*$b] - i \cdot \sqrt($[$c - 0.25*$b^2])
    !exit
!endif    

!if $R>3
    g=!randitem 1,4,9,16
    h=!randitem 1,4,9,16
    a=!randitem 1,2,3,4
    b=!randitem 1,2,3,4
    !if $[sqrt($g)]=$a
	a=$[$a+1]
    !endif	
    !if $[sqrt($h)]=$b
	b=$[$b+1]
    !endif
    c=$[2*$a]
    d=$[2*$b]
    e=$[-1*$a*$a+$b*$b+$g-$h]
    f=$[2*$a*$b+2*sqrt($g*$h)]
    opgave$n=z^{2} + ( $c-$d \cdot i) \cdot z - $e - $f \cdot i = 0
    GOED$n=$[sqrt($g)-$a] + i*$[(sqrt($h) + $b)],$[-1*sqrt($g)-$a] + i*$[(-1*sqrt($h) + $b)]
    goed$n=z= $[sqrt($g)-$a] + i\cdot $[(sqrt($h) + $b)] \vee z= $[-1*sqrt($g)-$a] + i\cdot $[(-1*sqrt($h) + $b)]
    !exit
!endif

# R>3 :

#    tussen=!exec pari ($f - 2*$a*$b)/(2*sqrt($g)) + $b\
#    (2*$a*$b - $f)/(2*sqrt($g)) + $b
#    t1=!line 1 of $tussen
#    t2=!line 2 of $tussen

#
#  z^2+(c -di)z -e-fi=0
#  (z + a - bi)^2 - (a - bi)^2 -e - fi=0
#  (z + a - bi)^2 - (a^2 -b^2 -2abi) -e -fi=0
#  (z + a - bi)^2 = a^2 - b^2 + e + ( -2ab + f)i
#  
#  (x+iy)^2 = a^2 - b^2 + e + ( -2ab + f)i
#  x^2 - y^2 + 2xyi = a^2 - b^2 + e + ( -2ab + f)i
#  
#  x^2-y^2 = a^2 - b^2 + e
#  2xy =-2ab + f
#  
#  DUS: y= (-2ab + f)/(2x) 
#  DUS: x^2 -(4a^2b^2 -4abf + f^2)/(4x^2) = a^2 - b^2 + e
#  x^4 + ( -a^2 + b^2 - e)*x^2 - ( a^2b^2 -abf + f^2/4) = 0
#  
#  (x^2 + h)(x^2 - g) =0
#  x^4 + ( h - g)x^2 - gh = 0
#  
#  DUS: h - g = -a^2 + b^2 - e
#  gh = a^2b^2 - abf + f^2/4
#  
#  DUS: e vastleggen
#  e = -a^2 + b^2 + g - h
#  f^2 -4abf + 4a^2b^2 - 4gh = 0
#  Discriminant: 4*sqrt(gh)
#  
#  DUS: f = 2ab + 2*sqrt(gh) 
#  OF: >> en deze vervalt <<  f = 2ab - 2*sqrt(gh)
