n=$teller
bewerking=bewerking1.proc
!if $graad=0
    R=$teller
!else
    R=$graad
!endif    
antwoord=$empty    
letter1=!randitem a,s,k,q,u,x,c,n,z 
letter2=!randitem b,g,m,r,v,y,d,p,t
!if $R=1
    !if $taal=nl
	nivo_title=Schrijf zo eenvoudig mogelijk:<br> optellen & aftrekken met &eacute;&eacute;n variabele	
    !else
	nivo_title=Rewrite as simple as possible:<br> addition & subtraction with one variable	
    !endif
    wims_rawmath_variables=$letter1
    varcnt=1
    controle=
    getallen=2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30
    getallen=!shuffle $getallen
    
    !for p=1 to $aantal_vragen

	keuze=!randitem 1,2
	getal1=!item $p of $getallen
	getal2=!item $[$p + 1] of $getallen
	mp=!randitem -1,1
	pm=!randitem +,-
	getal1=$[$mp*$getal1]

	!if $keuze=1
	    vraag=$getal1*$letter1 $pm $getal2*$letter1
	!else
	    getal3=!randitem 2,3,4,5
	    vraag=$getal1*$letter1^$getal3 $pm $getal2*$letter1^$getal3
	!endif	    
	som$p=!htmlmath $vraag
	controle=!append item $vraag to $controle
	GOED=!exec pari $vraag
	GOED$n=!append item $GOED to $(GOED$n)
	htmlgoed=!htmlmath $GOED
	antwoord=!append line <li>$(som$p) &nbsp;<font size="+1">=</font>&nbsp; $htmlgoed</li> to $antwoord
    !next p
!endif
!if $R=2
    !if $taal=nl
	nivo_title=Schrijf zo eenvoudig mogelijk:<br>delen & vermenigvuldigen met &eacute;&eacute;n variabele	
    !else
	nivo_title=Rewrite as simple as possible:<br> multiplication  & division with one variable	
    !endif
    wims_rawmath_variables=$letter1
    varcnt=1
    controle=
    getallen=2,3,4,5,6,7,8,9,10,11,12,13,14
    getallen=!shuffle $getallen

    !for p=1 to $aantal_vragen
	keuze=!randitem 1,2
	mp=!randitem -1,1
	pm=!randitem +,-

	!if $keuze=1
	    getal2=!item $p of $getallen
	    getal5=!randitem 3,4,5,6,7,8
	    getal1=$[$getal2*$getal5]
	    getal3=!randitem 4,5,6,7,8
	    getal4=!randitem 2,3,4,5,6
	    getal1=$[$mp*$getal1]
	    GOED=!exec pari $getal1*$letter1^$getal3/($getal2*$letter1^$getal4)
	    som$p=!htmlmath $getal1*$letter1^$getal3 : ($getal2*$letter1^$getal4)
	    controle=!append item $getal1*$letter1^$getal3/$getal2*$letter1^$getal4 to $controle
	!else
	    getal1=!item $p of $getallen
	    getal2=!item $[$p + 1] of $getallen
	    getal3=!item $[$p + 2] of $getallen
	    getal4=!item $[$p + 3] of $getallen 
	    getal1=$[$mp*$getal1]
	    som$p=!htmlmath $getal1*$letter1^$getal3 times $getal2*$letter1^$getal4
	    controle=!append item $getal1*$letter1^$getal3*$getal2*$letter1^$getal4 to $controle
	    GOED=!exec pari $getal1*$letter1^$getal3*$getal2*$letter1^$getal4
	!endif
	GOED$n=!append item $GOED to $(GOED$n)
	htmlgoed=!htmlmath $GOED
	antwoord=!append line <li>$(som$p) &nbsp;<font size="+1">=</font>&nbsp; $htmlgoed</li> to $antwoord
    !next p
!endif
!if $R=3
    controle=
    !if $taal=nl
	nivo_title=Schrijf zo eenvoudig mogelijk:<br> optellen & afrekken met twee variabelen	
    !else
    	nivo_title=Rewrite as simple as possible:<br> addition & subtraction with two variables	

    !endif
    wims_rawmath_variables=$letter1,$letter2
    varcnt=2
    getallen=2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20
    getallen=!shuffle $getallen
    !for p=1  to $aantal_vragen
	keuze=!randitem 1,2
	pm=!randitem +,-
	mp=!randitem +,-
	getal1=!item $p of $getallen
	getal2=!item $[$p + 1] of $getallen
	getal3=!item $[$p + 2] of $getallen
	getal4=!item $[$p + 3] of $getallen
	getal5=!item $[$p + 4] of $getallen
	getal6=!item $[$p + 5] of $getallen

	!if $keuze=1
	    controle=!append item $getal1*$letter1 $pm $getal2*$letter2 $mp $getal3*$letter2 $pm $getal4*$letter1 to $controle
	    som$p=!htmlmath $getal1*$letter1 $pm $getal2*$letter2 $mp $getal3*$letter2 $pm $getal4*$letter1
	    GOED=!exec pari $getal1*$letter1 $pm $getal2*$letter2 $mp $getal3*$letter2 $pm $getal4*$letter1
	!else
	    vraag=$getal1*$letter1^$getal5 $pm $getal2*$letter2^$getal6 $mp $getal3*$letter2^$getal6 $pm $getal4*$letter1^$getal5
	    controle=!append item $vraag to $controle
	    som$p=!htmlmath $vraag 
	    GOED=!exec pari $vraag
	!endif    
	GOED$n=!append item $GOED to $(GOED$n)
	htmlgoed=!htmlmath $GOED
	antwoord=!append line  <li>$(som$p) &nbsp;<font size="+1">=</font>&nbsp; $htmlgoed</li> to $antwoord
    !next p
!endif
!if $R>3
#bolleboosjes
    controle=
    !if $taal=nl
	nivo_title=Schrijf zo eenvoudig mogelijk:<br>delen & vermenigvuldigen met &eacute;&eacute;n of twee variabele	
    !else
	nivo_title=Rewrite as simple as possible:<br> multiplication  & division with one or two variables	
    !endif
    getallen=2,3,4,5,6,7,8,9,10,11,12,13,14,15,16
    getallen=!shuffle $getallen
    wims_rawmath_variables=$letter1
    varcnt=1
    !for p=1 to $aantal_vragen
	getal1=!item $p of $getallen
	getal2=!item $[$p + 1] of $getallen
	getal3=!item $[$p + 2] of $getallen
	getal4=!item $[$p + 3] of $getallen
	controle=!append item $letter1^$getal1/$letter1^$getal4 to $controle
    	som$p=!htmlmath $letter1^$getal1 : ($letter1^$getal4)
    	GOED=!exec pari ($letter1^$getal1)/(($letter1)^$getal4)
	GOED$n=!append item $GOED to $(GOED$n)
	htmlgoed=!htmlmath $GOED
	antwoord=!append line  <li>$(som$p) &nbsp;<font size="+1">=</font>&nbsp; $htmlgoed</li> to $antwoord
    !next p
!endif

PLAATJE=0
letterlijk=1
!if $taal=nl
    somtekst$n=Vul in en schrijf zo kort mogelijk.
    antwoord$n=<table width="100%"><td><ol>$antwoord</ul></td></table>
    hint=Geen hints bij deze som.<br>Zie voor syntax de help-pagina
!else
    somtekst$n=Fill in and simplify.
    antwoord$n=<table width="100%"><td><ol>$antwoord</ul></td></table>
    hint=No hint.<br>Look into the help-pages. 
!endif    