bewerking=bewerking2.proc
!set n=$teller
!if $taal=nl
    nivo_title=Los het volgende stelsel vergelijking op <br><font color=$fontcolor3>Twee vergelijkingen met twee onbekenden.</font>
!else
    nivo_title=Solve the set of equations<br><font color=$fontcolor3>Two equations with two variables.</font>
!endif

!if $graad =0
    R=$teller
!else
    R=$graad
!endif        

!if $variabelen=1
    letters=a,b,c,d,f,x,y,z,p,g,k,t,r,n,m
    letters=!shuffle $letters 
    X$n=!item 1 of $letters
    Y$n=!item 2 of $letters
!else
    X$n=x
    Y$n=y
!endif   
     	
a=!randitem 2,3,4,5,6,7,8
b=!randitem 2,3,4,5,6,7,8
!if $breuken=0
    G$n=!randitem 2,3,4,5,6,7,8,9,10,11,12,13,14,15
    GG$n=!randitem 2,3,4,5,6,7,8,9,10,12,13,14,15
    !if $R=1
	# X => G
        # Y => GG
	# x+y=c
	# x-y=d
	c=$[$(G$n)+$(GG$n)]
	d=$[$(G$n)-$(GG$n)]
	som$n=\left\{ \begin{array}{c}$(X$n) + $(Y$n) = $c \\ $(X$n) - $(Y$n) = $d \end{array}\right.
	extra$n=\left\{ \begin{array}{c}$(X$n) + $(GG$n) = $c  \Longrightarrow $(X$n)= $(G$n)\\ $(Y$n) = $(GG$n) \end{array}\right.
     !exit
    !endif
	
    !if $R=2 
	# X => G
        # Y => GG
	# bx+y=c
	# ax-y=d
	c=$[$b*$(G$n)+$(GG$n)]
	d=$[$a*$(G$n)-$(GG$n)]
	som$n=\left\{ \begin{array}{c}$b\cdot $(X$n) + $(Y$n) = $c \\ $a\cdot $(X$n) - $(Y$n) = $d \end{array}\right.
	extra$n=\left\{ \begin{array}{c}$(X$n)= $(G$n)\\ $(Y$n) = $(GG$n) \end{array}\right.
     !exit
    !endif
	
    !if $R=3 
	# X => G
        # Y => GG
	# x+by=c
	# ax-y=d
	c=$[$(G$n)+ $b*$(GG$n)]
	d=$[$a*$(G$n)-$(GG$n)]
	som$n=\left\{ \begin{array}{c}$(X$n) + $b\cdot $(Y$n) = $c \\ $a\cdot $(X$n) - $(Y$n) = $d \end{array}\right. 
	extra$n=\left\{ \begin{array}{c}$(X$n)= $(G$n)\\ $(Y$n) = $(GG$n) \end{array}\right.
     !exit
    !endif
	
    !if $R>3 
	# X => G
        # Y => GG
	# ax+by=c 
	# x+y=d 
        c=$[$a*$(G$n) + $b*$(GG$n)]
        d=$[$(G$n) + $(GG$n)]
        som$n=\left\{ \begin{array}{c} $a\cdot $(X$n) + $b\cdot $(Y$n) = $c \\ $(X$n) + $(Y$n) = $d \end{array}\right. 	
        extra$n=\left\{ \begin{array}{c}$(X$n)= $(G$n)\\ $(Y$n) = $(GG$n) \end{array}\right.
     !exit
    !endif
!else
    T1=!randitem 2,3,4,5,6,8,9,10,12    
    T2=!randitem 11,12,13,14,15,16,18,20
    NN=!randint 6,20    
    NN=$[2*$NN]
    TOT=!exec pari $T1/$NN \
    $T2/$NN
    
    G$n=!line 1 of $TOT
    GG$n=!line 2 of $TOT
    
    !if $R=1
	# X => G
        # Y => GG
	# x+y=c => c=G+GG
	# x-y=d => d=C-GG
	tot=!exec pari printtex($(G$n)+$(GG$n))\
	printtex($(G$n)-$(GG$n))	
	c=!line 1 of $tot
	d=!line 2 of $tot
	som$n=\left\{ \begin{array}{c}$(X$n) + $(Y$n) = $c \\ \\ $(X$n) - $(Y$n) = $d \end{array}\right.
	extra$n=\left\{ \begin{array}{c}$(X$n) + $(GG$n) = $c  \Longrightarrow $(X$n)= $(G$n) \\ \\ $(Y$n) = $(GG$n) \end{array}\right.
     !exit
    !endif
	
    !if $R=2 
	# X => G
        # Y => GG
	# bx+y=c => c=b*G +GG
	# ax-y=d => d=aG -GG
	tot=!exec pari printtex($b*$(G$n)+$(GG$n))\
	printtex($a*$(G$n)-$(GG$n))
	c=!line 1 of $tot
	d=!line 2 of $tot
	som$n=\left\{ \begin{array}{c}$b\cdot $(X$n) + $(Y$n) = $c \\ \\ $a\cdot $(X$n) - $(Y$n) = $d \end{array}\right.
	extra$n=\left\{ \begin{array}{c}$(X$n)= $(G$n) \\ \\ $(Y$n) = $(GG$n) \end{array}\right.
     !exit
    !endif
	
    !if $R=3 
	# X => G
        # Y => GG
	# x+by=c  => c= G+b*GG
	# ax-y=d => d=a*G - GG
	tot=!exec pari printtex($(G$n)+ $b*$(GG$n))\
	printtex($a*$(G$n)-$(GG$n))
	c=!line 1 of $tot
	d=!line 2 of $tot
	som$n=\left\{ \begin{array}{c}$(X$n) + $b\cdot $(Y$n) = $c \\ \\ $a\cdot $(X$n) - $(Y$n) = $d \end{array}\right. 
	extra$n=\left\{ \begin{array}{c}$(X$n)= $(G$n) \\ \\ $(Y$n) = $(GG$n) \end{array}\right.
     !exit
    !endif
	
    !if $R>3 
	# X => G
        # Y => GG
	# ax+by=c  => c=a*G +b*GG
	# x+y=d  => d=G+GG
	tot=!exec pari printtex($a*$(G$n) + $b*$(GG$n))\
	printtex($(G$n) + $(GG$n))
	c=!line 1 of $tot
	d=!line 2 of $tot
        som$n=\left\{ \begin{array}{c} $a\cdot $(X$n) + $b\cdot $(Y$n) = $c \\ \\ $(X$n) + $(Y$n) = $d \end{array}\right. 	
        extra$n=\left\{ \begin{array}{c}$(X$n)= $(G$n) \\ \\ $(Y$n) = $(GG$n) \end{array}\right.
     !exit
    !endif
!endif